Bicepによる Event Grid トリガーとバインドした Event Subscription の作成 (Flex Consumption のAzure Functionsの利用)

$ az functionapp list-flexconsumption-locations --output table
northeurope
southeastasia
eastasia
eastus2
southcentralus
australiaeast
eastus
northcentralus(stage)
westus2
uksouth
eastus2euap
westus3
swedencentral

param hostingPlanName string
param location string = resourceGroup().location
param tags object = {}
param sku object = {}

param kind string = 'linux'


//https://github.com/Azure/azure-quickstart-templates/blob/master/quickstarts/microsoft.web/app-function/main.bicep
resource hostingPlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: hostingPlanName
  location: location
  tags: tags
  kind: kind
  properties: {
    reserved: true
  }
  sku: sku
}

output id string = hostingPlan.id
output name string = hostingPlan.name

@description('Storage Account type')
@allowed([
  'Premium_LRS'
  'Premium_ZRS'
  'Standard_GRS'
  'Standard_GZRS'
  'Standard_LRS'
  'Standard_RAGRS'
  'Standard_RAGZRS'
  'Standard_ZRS'
])
param storageAccountType string = 'Standard_LRS'

@description('The storage account location.')
param location string = resourceGroup().location

param tags object = {}

@description('The name of the storage account')
param storageAccountName string

param containerNames array

resource sa 'Microsoft.Storage/storageAccounts@2023-01-01' = {
  name: storageAccountName
  location: location
  tags: tags
  sku: {
    name: storageAccountType
  }
  kind: 'StorageV2'
  properties: {}
}

resource blobServices 'Microsoft.Storage/storageAccounts/blobServices@2023-01-01' = {
  parent: sa
  name: 'default'
}

resource containers 'Microsoft.Storage/storageAccounts/blobServices/containers@2023-01-01' = [for containerName in containerNames: {
  parent: blobServices
  name: containerName
}]


output storageAccountName string = storageAccountName
output storageAccountId string = sa.id

targetScope = 'resourceGroup'

param location string = resourceGroup().location
@description('The environment designator for the deployment. Replaces {env} in namingConvention.')
@allowed([
  'dev' //Develop
  'stg' //Staging
  'prd' //Production
])
param enviromentName string = 'dev'
var enviromentResourceNameWithoutHyphen = replace(enviromentName, '-', '')

@allowed(['northeurope', 'southeastasia', 'eastasia', 'eastus2', 'southcentralus', 'australiaeast', 'eastus', 'westus2', 'uksouth', 'eastus2euap', 'westus3', 'swedencentral'])
param hostingPlanLocation string = 'eastus2'

@description('The workload name. Replaces {workloadName} in namingConvention.')
param workloadName string = 'pj'

param deploymentStorageContainerName string = 'app-pkg-func'
param eventGridContainerName string = 'eventcontainer'


var suffixResourceName = '-${workloadName}'
var suffixResourceNameWithoutHyphen = replace(suffixResourceName, '-', '')

param convertedEpoch int = dateTimeToEpoch(dateTimeAdd(utcNow(), 'P1Y'))

var abbrs = json(loadTextContent('abbreviations.json'))

var tags = {
  workload: workloadName
  environment: enviromentName
}

//https://learn.microsoft.com/ja-jp/dotnet/api/microsoft.azure.management.operationalinsights.models.workspacesku?view=azure-dotnet-legacy
////https://github.com/mspnp/microservices-reference-implementation/blob/e903447c7b8b6af6302a5f5a7c672572471d01e4/azuredeploy.bicep#L77
module logAnalyticsWorkspace 'modules/monitor/logAnayticsWorkspace.bicep' = {
  name: 'logAnalyticsWorkspace'
  params:{
    logAnalyticsName: '${abbrs.operationalInsightsWorkspaces}${enviromentName}${suffixResourceName}'
    location: location
  }
}

module appInsights 'modules/monitor/appInsights.bicep' = {
  name: 'appInsights'
  params:{
    name: '${abbrs.insightsComponents}${enviromentName}${suffixResourceName}'
    location: location
    tags: tags
    logAnalyticsWorkspaceId: logAnalyticsWorkspace.outputs.id
  }
}

module storage 'modules/storage/storage.bicep' = {
  name: 'storage'
  params: {
    storageAccountName: '${abbrs.storageStorageAccounts}${enviromentResourceNameWithoutHyphen}${suffixResourceNameWithoutHyphen}'
    location: location
    tags: tags
    storageAccountType: 'Standard_LRS'
    containerNames: [deploymentStorageContainerName]
  }
}


module evetGridStorage 'modules/storage/storage.bicep' = {
  name: 'evetGridStorage'
  params: {
    storageAccountName: '${abbrs.storageStorageAccounts}${enviromentResourceNameWithoutHyphen}egst${suffixResourceNameWithoutHyphen}'
    location: location
    tags: tags
    storageAccountType: 'Standard_LRS'
    containerNames: [eventGridContainerName]
  }
}

var aspSku = {
  tier: 'FlexConsumption'
  name: 'FC1'
}


module hostingPlan 'modules/host/asp.bicep' = {
  name: 'hostingPlan'
  params:{
    hostingPlanName: '${abbrs.webServerFarms}${enviromentName}${suffixResourceName}'
    location: !empty(hostingPlanLocation) ? hostingPlanLocation : location
    tags: tags
    sku: aspSku
    kind: 'functionapp,linux'
  }
}

module flexFunction 'modules/function/flexFunction.bicep' = if(aspSku.tier == 'FlexConsumption'){
  name: 'flexFunction'
  params:{
    functionName: '${abbrs.webSitesFunctions}${enviromentName}-flex${suffixResourceName}'
    location: hostingPlanLocation
    tags: tags
    hostingPlanName: hostingPlan.outputs.name
    storageAccountName: storage.outputs.storageAccountName
    applicationInsightsName: appInsights.outputs.appInsightsName
    functionAppRuntime: 'python'
    functionAppRuntimeVersion: '3.11'
    deploymentStorageContainerName: deploymentStorageContainerName
    eventGridStorageAccountName: evetGridStorage.outputs.storageAccountName
  }
}

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "location": {
      "value": "eastus2"
    },
    "enviromentName": {
      "value": "dev"
    },
    "hostingPlanLocation": {
      "value": "eastus2"
    },
    "workloadName": {
      "value": "pj-bicep"
    },
    "deploymentStorageContainerName": {
      "value": "app-pkg-func-flex"
    }
  }
}

az deployment group create \
  --name {Resource Group 名}-deploy \
  --mode Complete \
  --resource-group {Resource Group 名} \
  --confirm-with-what-if \
  --template-file ./main.bicep \
  --parameters ./main.parameters.dev.json

  deploy:
    runs-on: ubuntu-22.04
    environment: 'dev'
    steps:
      - name: Run Azure Functions Action.
        uses: Azure/functions-action@v1.5.2
        id: deploy-to-function
        with:
          app-name: ${{ vars.AZURE_FUNCTIONAPP_NAME }}
          package: ${{ env.DOWNLOAD_ARTIFACT_DIRPATH }}
          publish-profile: ${{ secrets.AZURE_FUNCTIONAPP_PUBLISH_PROFILE }}
          sku: flexconsumption
          remote-build: false

import logging
import azure.functions as func

app = func.FunctionApp()

@app.function_name(name="eventGridTrigger01")
@app.event_grid_trigger(arg_name="event")
def event_grid_trigger(event: func.EventGridEvent):
    """Process an event grid trigger for a new blob in the container."""
    logging.info("Processing event %s", event.id)

param name string

resource storage 'Microsoft.Storage/storageAccounts@2023-01-01' existing = {
  name: name
}

output id string = storage.id
output name string = storage.name
output location string = storage.location

@description('The name of the Event Grid custom topic.')
param eventGridSystemTopicName string = 'topic-${uniqueString(resourceGroup().id)}'

@description('The name of the Event Grid custom topic\'s subscription.')
param eventGridSystemTopicSubscriptionName string = 'sub-${uniqueString(resourceGroup().id)}'

param location string = resourceGroup().location

param storageAccountId string

param tags object = {}

param functionAppName string

param functions array

// Microsoft.EventGrid/systemTopics の作成する
// https://github.com/Azure/azure-quickstart-templates/blob/master/quickstarts/microsoft.eventgrid/event-grid-subscription-and-storage/main.bicep
resource systemTopic 'Microsoft.EventGrid/systemTopics@2023-12-15-preview' = {
  name: eventGridSystemTopicName
  location: location
  identity: {
    type: 'SystemAssigned'
  }
  tags: tags
  properties: {
    source: storageAccountId
    topicType: 'Microsoft.Storage.StorageAccounts'
  }
}

// 関数の数分、Event Grid Subscription を作成する
resource eventSubscription 'Microsoft.EventGrid/systemTopics/eventSubscriptions@2023-12-15-preview' = [for function in functions: {
  parent: systemTopic
  name: '${eventGridSystemTopicSubscriptionName}-${function.name}'
  properties: {
    destination: {
      endpointType: 'AzureFunction'
      properties: {
        resourceId: resourceId('Microsoft.Web/sites/functions', functionAppName, function.name)
      }
    }
    eventDeliverySchema: 'EventGridSchema'
    filter: {
      includedEventTypes: function.includedEventTypes
    }
  }
}]

{
    "operationalInsightsWorkspaces": "log-",
    "insightsComponents": "appi-",
    "storageStorageAccounts": "st",
    "webServerFarms": "plan-",
    "webSitesFunctions": "func-",
    "eventGridSystemTopics": "egst-"
  }

targetScope = 'resourceGroup'

@minLength(1)
@maxLength(16)
@description('Name of the the environment which is used to generate a short unique hash used in all resources.')
param environmentName string = 'test'

@description('The workload name. Replaces {workloadName} in namingConvention.')
param workloadName string = 'pj'

var suffixResourceName = '-${workloadName}'
var suffixResourceNameWithoutHyphen = replace(suffixResourceName, '-', '')

param eventGridFunctionsInJson object
var eventGridFunctions = eventGridFunctionsInJson.eventGridFunctions

param eventGridStorageName string

param functionAppName string

var tags = { 'workload': workloadName, 'environment': environmentName }

var abbrs = loadJsonContent('./abbreviations.json')

// Event Grid 用のストレージアカウントを参照する。
module eventGridStorage './modules/storage/storage.bicep' = {
  name: 'eventGridStorage'
  params: {
    name: eventGridStorageName
  }
}

// NOTE: Function App に Event Grid Trigger を追加後に、Event Grid System Topic と Event Grid Subscription を作成する。
// Event Grid (System Topic) , Event Grid Subscription を作成する。
// https://learn.microsoft.com/ja-jp/azure/templates/microsoft.storage/storageaccounts/blobservices/containers?pivots=deployment-language-bicep
// https://learn.microsoft.com/ja-jp/azure/templates/microsoft.eventgrid/eventsubscriptions?pivots=deployment-language-bicep
module eventGridSystemTopic './modules/event/systemTopic.bicep' = {
  name: 'eventGridSystemTopic'
  params: {
    eventGridSystemTopicName: '${abbrs.eventGridSystemTopics}${environmentName}${suffixResourceName}'
    eventGridSystemTopicSubscriptionName: '${abbrs.eventGridEventSubscriptions}${environmentName}${suffixResourceName}'
    location: eventGridStorage.outputs.location  //NOTE: eventGrid Storage と同じ Region にする
    storageAccountId: eventGridStorage.outputs.id
    functionAppName: functionAppName
    functions: eventGridFunctions
    tags: tags
  }
}

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "environmentName": {
      "value": "dev"
    },
    "workloadName": {
      "value": "pj-bicep"
    },
    "eventGridStorageName": {
      "value": "stdevegstpjbicep"
    },
    "functionAppName": {
      "value": "func-dev-flex-pj-bicep"
    },
    "eventGridFunctionsInJson": {
      "value": {"eventGridFunctions":[{"name": "eventGridTrigger01", "includedEventTypes": ["Microsoft.Storage.BlobCreated"]}]}
    }
  }
}

az deployment group create \
  --name {Resource Group 名}-deploy-eventgrid \
  --mode Incremental \
  --resource-group {Resource Group 名} \
  --confirm-with-what-if \
  --template-file ./main.bicep \
  --parameters ./main.parameters.dev.json